
 beginoutdoorscript;

 variables;

int i,j,k,r1,choice;

 body;

 beginstate INIT_STATE;

	break;

 beginstate START_STATE;
	if (get_flag(203,1) == 5)
		set_terrain(19,34,137);

	break;

 beginstate 10;
	if (get_flag(203,0) <= 1)
		create_out_spec_enc(0);

	if (get_flag(203,0) == 0) {
		message_dialog("Charging head on was not a smart move. You were right, there were many demons in the fortifications and they look far stronger than what you've seen before. Also, to your horror, some of them are haakai.","");
		set_flag(203,0,1);
		set_creature_type_level(242,50);
		set_creature_type_level(60,45);
}
	if ((get_flag(203,1) == 5) && (get_flag(203,3) == 0)) {
		create_out_spec_enc(1);
		message_dialog("The remaining haakai and his minions attack you.","");
}
		
break;

 beginstate 11;
	if (get_flag(203,1) == 0) {
		message_dialog("From here you can see fortifications blocking a narrow passage to the north. Upon closer inspection, you see that the fortifications are controlled by demons, and there are a lot of them.","Possibly the demons destroyed the town of Norton. Answers lie in the northern valley, but you should find another way there.");
		set_flag(203,1,1);
}

	if (get_flag(203,1) == 3) {
		message_dialog("The demon garrison collapses into a fine pile of rubble. You were close enough to witness what happened. There were apparently two or more haakais in the garrison. They started fighting each other for some reason.","Remembering what Bastaricus told you about the hierarchical nature of hell, you figure that with their master gone, the haakais fought for Kaejil Nyh'yltak's position. The fight was devastating and one of the haakais remains.");
		set_flag(203,1,5);
		set_terrain(19,34,137);
}
 break;

 beginstate 12;
	set_flag(203,0,2);
	message_dialog("The fight was devastating but you prevailed. You search the garrison in hopes of finding some clues about the demons. You find nothing. You can only hope this was the bulk of the demon forces.","Otherwise you might be in big trouble.");
	set_creature_type_level(242,30);
	set_creature_type_level(60,25);
 break;

 beginstate 13;
	if (get_flag(208,0) == 0) {
		message_dialog("Your little boating trip has lead you to a horrific site. The city ahead of you is in ruins. It has been completely annihilated. Some of the buildings have even crumbled to the ground.","After the initial shock, you begin to wonder. How is it possible that an Empire city has been destroyed and no-one seems to know of it? Faerengrove is a backwater, but surely something like this would have been reported.");
		set_flag(208,0,1);
}
break;

 beginstate 14;
	if (get_flag(203,2) == 0) {
		message_dialog("You've come to the location of the ancient fortress. The source of all the suffering has taken the fortress as its new home. Even now demons are patrolling around it.","");
		set_flag(203,2,1);
}
 break;

 beginstate 15;
	set_out_fight_town_loaded(19);
 break;

 beginstate 16;
	if ((get_flag(17,17) >= 2) && (get_flag(17,9) == 1) && (get_flag(203,0) < 2)) {
		message_dialog("You notice smoke coming from the direction of the demon garrison. Someone has attacked the garrison and managed to cause quite a fuss. Who could it be?","");
		set_flag(203,0,5);
		set_flag(203,1,3);
}
 break;

 beginstate 17;
	set_flag(203,3,1);
 break;